“2560战法”探讨及公式代码

1、网上流传的“2560战法”公式

网上流传的“2560战法”公式一套共3个，分别是—2560战法主图、2560战法副图和2560战法选股，源代码如下：

（1）2560战法主图

MAH:=8;
MAL:=20;
MA5:MA(C,5),LINETHICK2;
MA10:=MA(C,10);
MA25:MA(C,25),LINETHICK2;
MA60:MA(C,60);
MA120:=MA(C,120);
MA250:MA(C,250);
IF(MA25<REF(MA25,1),MA25,DRAWNULL),COLORGREEN, LINETHICK2;
PP1:=H>=MA(C,5)*(100+MAH)/100;
PP2:=L*(100+MAL)/100<=MA(C,25);
DRAWICON(PP1,H*1.02,15);
DRAWICON(PP2,L*0.97,26);
STICKLINE(CROSS(MA(C,5),MA(C,25)),O,C,1,0),COLORYELLOW;
DRAWICON((MA(C,4)*4+MA(C,25))/5>=MA(C,25) AND MA(C,5)<MA(C,25),L*0.97,1);

（2）2560战法副图

M1:=5;
M2:=60;
N:=15;
​
预测量:IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,VOL),VOLSTICK;
MAVOL1:MA(预测量,M1);
MAVOL2:MA(预测量,M2);
BB:=CROSS(MAVOL1,MAVOL2);
CC:=CROSS(MAVOL2,MAVOL1);
STICKLINE(BB,0,VOL,1,0),COLORYELLOW;
STICKLINE(CC,0,VOL,1.5,0),COLORGREEN;
地量:=V<=LLV(V,N);
DRAWICON(地量,MA(VOL,60),25);
DRAWICON((MA(V,4)*4+V)/5>=MA(V,60) AND MA(V,5)<MA(V,60),预测量*1.2,1);

（3）2560战法选股

{25日均线已经拐头向上，5日均线上穿25日均线，5日均量大于60日均量 }
VAR1:=MA(C,25);
VAR2:=MA(C,5);
VAR3:=MA(V,5);
VAR4:=MA(V,60);
VAR5:=VAR1 > REF(VAR1,1);
VAR6:=CROSS(VAR2,VAR1);
VAR7:=VAR3>VAR4;
VAR5 AND VAR6 AND VAR7;

（4）下面是对2560战法选股测试胜率，

程序交易评测设置报告 评测公式：条件选股公式-(日线)-2560战法选股 评测时段：2023/01/15-2024/01/15 向前多取100个数据用于计算 强制平仓计入收益 评测品种：5000只 初始投入1000000元 开仓条件：条件选股公式发出的开仓信号 开仓方式：固定数量开仓 股票: 100股，期货/期权: 1手 平仓条件：公式中定义的平仓条件 止损平仓：按当日收盘价计算是否满足止损条件,按本周期收盘价平仓 最大损失止损平仓：与开仓资金相比亏损达到10%,则全部数量平仓 最大收益止盈平仓：与开仓资金相比收益达到10%,则全部数量平仓 目标周期平仓：开仓达到1，3，9，15，20，25个周期分别测试,全部数量平仓

(a) 1周期的胜率部分标的结果：

(b) 1周期-25周期测试结果：

(c)测试结论：

20周期基本上市胜率最高点45.47%，胜率比较低。

2、“2560战法”公式探讨

“2560战法”只是表述了期货市场，原作者对股票市场没有表述。A股市场是T+1市场交易结算规则，日内频繁交易几乎不可能。

25日均线作为参考均线也是有一定道理的。

指标布林线中轨一般是20日均线，市场投资者都是以20均线作为参考，市场主力在上涨过程中会有意出现一天跌破20日均线的行为，25日均线作为多头参考点就比较合理，不过测试过50~60日均线作为多头参考点，胜率比较高。

“2560战法”精髓就是：25日均线坚决向上，5日均线上穿或回踩25日均线时，成交量5均量大于60均量就是介入机会，最好此时出现缩量小星线过渡。

下面对这句精髓逐句代码实现：

25日均线坚决向上，

M25:=MA(C,25)/REF(MA(C,25),2)>=0.95;
M60:=MA(C,60)/REF(MA(C,60),2)>=0.95; {60日均线走平回避下跌趋势25日均线走平骗线}
MM:= M25 AND M60; {25日均线走平向上}
B:=CROSS(C,MA(C,25)); {突破25日均线}
A:=EVERY(C>MA(C,25),BARSLAST(B)); {突破25日均线后持续保持收盘价在25日均线之上}

5日均线上穿或回踩25日均线时，成交量5日均量大于60日均量就是介入机会，

B1:=CROSS(MA(C,5),MA(C,25));   {5日均线上穿25日均线}
B2:=MA(C,5)<REF(MA(C,5),1) AND MA(C,5)>MA(C,25);  {5日均线回踩25日均线}
预测量:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,VOL);
MAVOL1:=MA(预测量,5);
MAVOL2:=MA(预测量,60);
VL:=MAVOL1>MAVOL2*0.92;     {成交量5日均量大于60日均量，这里做了些调整，有些个股主力有意下破一点，又拉回，加了系数0.92，可以设为参数，调整}
A:=EVERY(VL,BARSLAST(B1)) OR EVERY(VL,BARSLAST(B2));  {5日均线上穿或回踩25日均线时，成交量5日均量大于60日均量}
​

最好此时出现缩量小星线过渡

小星线:=(H-L)*100/L<5 AND ABS(O-C)/O*100<3; {小星线，}
地量:=V<=LLV(V,4); {4天内地量}
A1:=EXIST(小星线 AND 地量,BARSLAST(B1) OR BARSLAST(B2) ); {5日均线上穿25日均线或者5日均线回踩25日均线期间，出现缩量小星线}

选股器为：

M25:=MA(C,25)/REF(MA(C,25),2)>=0.95;
M60:=MA(C,60)/REF(MA(C,60),2)>=0.95;{60日均线走平回避下跌趋势25日均线走平骗线}
M2560:=M25 AND M60;  {25日均线走平向上}
B:=CROSS(C,MA(C,25));  {突破25日均线}
A:=EVERY(C>MA(C,25),BARSLAST(B)); {突破25日均线后持续保持收盘价在25日均线之上}
​
B1:=CROSS(MA(C,5),MA(C,25));   {5日均线上穿25日均线}
B2:=MA(C,5)<REF(MA(C,5),1) AND MA(C,5)>MA(C,25);  {5日均线回踩25日均线}
预测量:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,VOL);
MAVOL1:=MA(预测量,5);
MAVOL2:=MA(预测量,60);
BB:=CROSS(MAVOL1,MAVOL2);
VL:=MAVOL1>MAVOL2*0.92;     {成交量5日均量大于60日均量}
A1:=EVERY(VL,BARSLAST(B1)) OR EVERY(VL,BARSLAST(B2));  {5日均线上穿或回踩25日均线时，成交量5日均量大于60日均量}
​
小星线:=(H-L)*100/L<5 AND ABS(O-C)/O*100<3; {小星线}
地量:=V<=LLV(V,4); {4天内地量}
A2:=EXIST(小星线 AND 地量,BARSLAST(B1) OR BARSLAST(B2) ); {出现缩量小星线}
​
​
XG:M2560 AND A AND A1 AND A2 ;

胜率测试结果：

胜率还是比较低，最高只有1周期的43.5%。

技术指标表现如下图：

3、“2560战法”公式在T+1股票市场使用建议

（1）只是描述了所有牛的股票都是从25日均线走平向上开始的；

（2）在突破25日均线时或者后都需要出现放量上涨，实现5日均量线上穿60日均量线；

（3）放量突破25日均线后的调整最好是缩量小星线；

（4）突破25日均线，乖离率不大的话，第4天，第9天都是需要重视的，乖离率大的，调整时间就会长些，会出现第一次回抽25日均线；

（5）“2560战法”是股票上涨的一种现象，很难说明这种战法成功率很高，也是右侧交易的一种描述，骗线次数较多，失败率还是比较高的，从公式测试胜率也就是43%说明，操作难度很大，需要有很好的盘感和选股能力。

(以上内容仅供参考，不构成操作建议。仅供研究学习交流使用，如自行操作，注意仓位控制，风险自负。)